nl PSPP - a program for statistical analysis.   -*- autotest -*-
dnl Copyright (C) 2017 Free Software Foundation, Inc.
dnl
dnl This program is free software: you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation, either version 3 of the License, or
dnl (at your option) any later version.
dnl
dnl This program is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
dnl

AT_INIT

m4_ifdef([AT_COLOR_TESTS], [AT_COLOR_TESTS])

# Define SKIP_IF for compatibility with Autotest before 2.64
m4_ifndef([AT_SKIP_IF],
  [m4_define([AT_SKIP_IF],
     [AT_CHECK([($1) \
&& exit 77 || exit 0], [0], [ignore], [ignore])])])

m4_divert_text([PREPARE_TESTS], [dnl
if test -z "$RUNNER" && test -z "$AUTOTEST_PATH"; then
    echo >&2 "Use \"make check\" to run the testsuite."
    exit 1
fi

if test X"$RUNNER" != X; then
    wrapper_dir=`pwd`/wrappers
    rm -f "$wrapper_dir"/*
    test -d "$wrapper_dir" || mkdir "$wrapper_dir"

    wrap_dir () {
        test -d "$1" || return
	for file in "$1"/*; do
            if test -x "$file" && test -f "$file"; then
		base=`basename $file $EXEEXT`
		wrapper=$wrapper_dir/$base
		if test ! -e "$wrapper"; then
		    echo "exec $RUNNER $file \"\$@\"" > $wrapper
		    chmod +x $wrapper
		fi
	    fi
	done
    }

    save_IFS=$IFS; IFS=$PATH_SEPARATOR
    for dir in $AUTOTEST_PATH; do
        IFS=$save_IFS
        test X"$dir" = X && dir=.
	case $dir in
            [\\/]* | ?:[\\/]*)
                wrap_dir "$dir"
		;;
            *)
	        wrap_dir "$abs_top_builddir/$dir"
		wrap_dir "$abs_top_srcdir/$dir"
		;;
	esac
    done
    IFS=$save_IFS
    PATH=$wrapper_dir:$PATH
fi
])
